[Learn OpenGL] Shaders - 1

쉐이더는 GPU에 존재하는 작은 프로그램들로, 그래픽 파이프라인의 특정 부분마다 실행됩니다.

 

기본적으로, 쉐이더는 입력을 출력으로 변환하는 프로그램에 불과합니다.

 

쉐이더는 서로 통신할 수 없는 매우 독립적인 프로그램이며, 입력과 출력을 통해서만 통신할 수 있습니다.

 

이전 장에서 우리는 쉐이더와 그 사용 방법에 대해 간단히 다루었습니다. 이제 쉐이더, 특히 OpenGL Shading Language에 대해 좀 더 일반적으로 설명하겠습니다.

 

GLSL

쉐이더는 C와 유사한 언어인 GLSL로 작성됩니다. GLSL은 그래픽용으로 제작되었으며 벡터와 행렬 조작에 특화된 유용한 기능을 포함하고 있습니다.

 

쉐이더는 항상 버전 선언으로 시작한 후, 입력 및 출력 변수, 유니폼 및 메인 함수의 목록이 이어집니다.

 

각 쉐이더의 진입점은 입력 변수를 처리하고 결과를 출력 변수에 출력하는 메인 함수입니다.

 

유니폼이 무엇인지 모르더라도 걱정하지 마세요. 우리는 곧 그것에 대해 설명할 것입니다.

 

쉐이더는 일반적으로 다음과 같은 구조를 가집니다.

 

#version version_number
in type in_variable_name;
in type in_variable_name;

out type out_variable_name;
  
uniform type uniform_name;
  
void main()
{
  // 입력 처리 및 일부 그래픽 작업 수행
  ...
  // 처리된 내용을 출력 변수에 출력
  out_variable_name = weird_stuff_we_processed;
}

 

정점 쉐이더에 관해서는, 각 입력 변수를 정점 속성이라고도 합니다.

 

하드웨어에 의해 제한되는 정점 속성의 최대 개수가 있으며, OpenGL은 항상 최소 16개의 4-컴포넌트 정점 속성을 보장합니다.

 

하지만 일부 하드웨어에서는 더 많은 것을 허용할 수 있으며, GL_MAX_VERTEX_ATTRIBS를 조회하여 확인할 수 있습니다.

 

int nrAttributes;
glGetIntegerv(GL_MAX_VERTEX_ATTRIBS, &nrAttributes);
std::cout << "Maximum nr of vertex attributes supported: " << nrAttributes << std::endl;

 

Types

GLSL은 다른 프로그래밍 언어처럼, 우리가 작업하고자 하는 변수의 종류를 지정하기 위한 데이터 타입을 가지고 있습니다.

 

GLSL에는 C 언어와 같은 언어에서 알고 있는 대부분의 기본 기본 타입이 있습니다.

 

int, float, double, uint, bool. 또한 GLSL에는 벡터와 행렬 두 가지 컨테이너 타입이 있으며, 이들은 자주 사용될 것입니다.

 

행렬에 대해서는 나중에 다룰 예정입니다.

 

Vectors

GLSL의 벡터는 방금 언급한 기본 타입의 2, 3, 또는 4개 구성 요소를 가진 컨테이너입니다.

 

다음과 같은 형태를 취할 수 있습니다(n은 구성 요소의 수를 나타냅니다)

 

vecn: n개의 float로 구성된 기본 벡터.

bvecn: n개의 boolean으로 구성된 벡터.

ivecn: n개의 integer로 구성된 벡터.

uvecn: n개의 unsigned integer로 구성된 벡터.

dvecn: n개의 double 구성 요소로 구성된 벡터.

 

대부분의 경우, float이면 충분하기 때문에 기본적인 vecn을 사용할 것입니다.

 

벡터의 구성 요소는 vec.x와 같은 방식으로 접근할 수 있으며, 여기서 x는 벡터의 첫 번째 구성 요소입니다.

 

.x, .y, .z, .w를 사용하여 각각 첫 번째, 두 번째, 세 번째, 네 번째 구성 요소에 접근할 수 있습니다.

 

GLSL은 색상에 대해 rgba나 텍스처 좌표에 대해 stpq를 사용하여 동일한 구성 요소에 접근할 수 있도록 허용합니다.

 

 

벡터 데이터 타입은 스위즐링이라고 불리는 흥미롭고 유연한 구성 요소 선택을 허용합니다.

 

스위즐링을 사용하면 다음과 같은 문법을 사용할 수 있습니다.

 

vec2 someVec;
vec4 differentVec = someVec.xyxx;
vec3 anotherVec = differentVec.zyw;
vec4 otherVec = someVec.xxxx + anotherVec.yxzy;

 

최대 4개의 문자를 사용하여 새로운 벡터(동일한 타입)를 생성할 수 있으며, 원래 벡터가 해당 구성 요소를 가지고 있는 한 가능합니다;

 

예를 들어, vec2의 .z 구성 요소에 접근하는 것은 허용되지 않습니다.

 

또한 벡터를 다른 벡터 생성자 호출의 인수로 전달하여 필요한 인수의 수를 줄일 수 있습니다.

 

vec2 vect = vec2(0.5, 0.7);
vec4 result = vec4(vect, 0.0, 0.0);
vec4 otherResult = vec4(result.xyz, 1.0);

 

따라서 벡터는 입력과 출력에 사용할 수 있는 유연한 데이터 타입입니다.

 

이 책을 통해 벡터를 창의적으로 관리하는 다양한 예를 볼 수 있을 것입니다.

 

Ins and outs

쉐이더는 자체적으로 멋진 작은 프로그램이지만, 전체의 일부로 동작하기 때문데

 

개별 쉐이더에 입력과 출력이 있어야 합니다. 이를 통해 데이터를 이동시킬 수 있습니다.

 

GLSL은 이 목적을 위해 in과 out 키워드를 정의했습니다.

 

출력 변수가 다음 쉐이더 단계의 입력 변수와 일치할 경우 전달됩니다.

 

 

vertex shader는 어떤 형태의 입력을 받아야 하며, 그렇지 않으면 굉장히 비효율적이게 됩니다.

 

정점 쉐이더는 입력을 정점 데이터로 부터 직접 받는다는 점에서 다릅니다.

 

정점 데이터의 구성을 정의하기 위해 위치 메타데이터와 함께 입력 변수를 지정하여 CPU에서 정점 속성을 구성할 수 있습니다.

 

이전 장에서 laouy(location = 0) 으로 이를 보았습니다.

 

따라서 정점 쉐이더는 정점 데이터와 연결하기 위해 입력에 대한 추가 레이아웃 사양이 필요합니다.

 

 

fragment shader는 vec4 색상 출력 변수가 필요합니다.

 

색상 출력을 지정하지 않으면 일반적으로 OpenGL은 이를 검은색이나 흰색으로 렌더링 합니다.

 

 

타입과 이름이 양쪽 쉐이더에서 동일하면 OpenGL은 이러한 변수를 연결하고 프로그램 객체를 연결할 때

 

쉐이더 간에 데이터를 보낼 수 있습니다.

 

 

Vertex Shader

#version 330 core
layout (location = 0) in vec3 aPos; // the position variable has attribute position 0
  
out vec4 vertexColor; // specify a color output to the fragment shader

void main()
{
    gl_Position = vec4(aPos, 1.0); // see how we directly give a vec3 to vec4's constructor
    vertexColor = vec4(0.5, 0.0, 0.0, 1.0); // set the output variable to a dark-red color
}

 

Fragment Shader

#version 330 core
out vec4 FragColor;
  
in vec4 vertexColor; // the input variable from the vertex shader (same name and same type)  

void main()
{
    FragColor = vertexColor;
}

 

위에서 정점 쉐이더에 vec4 출력으로 vertexColor 변수를 선언하고 설정하고,

 

fragment shader에서 vertexColor를 입력으로 선언하는 것을 볼 수 있습니다.

 

두 변수 모두 같은 타입과 이름을 가지므로, 조각 쉐이더의 vertexColor는 정점 쉐이더의 vertexColor와 연결됩니다.

 

정점 쉐이더에서 색상을 어두운 빨간색으로 설정했기 때문에, 결과적으로 생성되는 조각들도 어두운 빨간색이어야 합니다. 다음 이미지는 출력 결과를 보여줍니다.